home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / asmutil / 80x0393.zip / DRAWCHAR.ASM < prev    next >
Assembly Source File  |  1992-07-30  |  7KB  |  193 lines
  1. ;
  2. ;  DRAWCHAR.ASM
  3. ;
  4. ;  Author: Matt Pritchard
  5. ;  Released to public domain
  6. ;
  7. ;Assumes Character set of 128 x 8 Bytes 
  8. ;  Character Set has a 16 byte Scratch Buffer at end.... 
  9. ; 
  10. ;GPRINTC (CharSet, CharNum, Xpos, Ypos, ColorF, ColorB) 
  11. ; 
  12. ; in "C"
  13. ;void GPRINTC(far char* SetData, int CharNum, int Xpos, 
  14. ;              int Ypos, int Color_Fg, int Color_Bg) 
  15. ; 
  16. ; in "BASIC" 
  17. ;TYPE CharSET 
  18. ;    BitMaps AS STRING * 1024 
  19. ;    Scratch AS STRING * 16 ;END TYPE 
  20. ; 
  21. ;DIM SetData AS CharSET 
  22. ; 
  23. ;DECLARE SUB GPRINTC(SEG SetData AS ANY, BYVAL CharNum%, BYVAL Xpos%,_ 
  24. ;                    BYVAL Ypos%, BYVAL ColorF%, BYVAL ColorB%) 
  25. ; 
  26. ; 
  27. ;Draws Text Character (8x8) in Graphics Mode 13 at Pixel (Xpos,Ypos) 
  28. ;In Color: COLORF with background of COLORB 
  29. ;
  30.  
  31.         .MODEL  Medium
  32.         .CODE
  33.  
  34. SCRATCH_OFS     EQU     1024+2  ;Character Set Working Area Offset 
  35. VGA_SEGMENT     EQU     0A000H  ;Vga Memory Segment 
  36. SCREEN_WIDTH    EQU     320     ;Width of screen in Pixels/Bytes
  37.  
  38. GPC_STACK       STRUC
  39.                         DW      ?       ;DI
  40.                         DW      ?       ;SI
  41.                         DW      ?       ;DS
  42.                         DW      ?       ;BP
  43.                         DD      ?       ;Caller
  44.         GPC_COLORB      DB      ?,?     ;Background Color
  45.         GPC_COLORF      DB      ?,?     ;Forground Color
  46.         GPC_YPOS        DW      ?       ;Y position
  47.         GPC_XPOS        DW      ?       ;X position
  48.         GPC_CHAR_NUM    DB      ?,?     ;Character #
  49.         GPC_SET_OFS     DW      ?       ;Offset of Set Data
  50.         GPC_SET_SEG     DW      ?       ;Segment of Set Data GPC_STACK
  51. ENDS
  52.  
  53.         PUBLIC GPRINTC
  54.  
  55. GPRINTC         PROC    FAR
  56.  
  57.         PUSH    BP
  58.         PUSH    DS                      ;Save Data Seg
  59.         PUSH    SI                      ;BC7 - Save Si,DI, Dir Flag
  60.         PUSH    DI
  61.  
  62.         MOV     BP,SP                   ;Set to address of bp
  63.  
  64.  
  65.         ;Compute Screen Addr to Write to in ES:DI
  66.  
  67.         MOV     AX,[BP].GPC_YPOS        ;Get Value of Ypos (mult * 320)
  68.         MOV     DH,AL                   ;Save 256*Y
  69.         MOV     CL,6                    ;mult * 2^6 (Y * 64)
  70.         SHL     AX,CL                   ;Shift Left
  71.         ADD     AH,DH                   ;Add in 256 * Ypos
  72.  
  73.         ADD     AX,[BP].GPC_XPOS        ;Add X position to addr
  74.  
  75.         MOV     DI,AX                   ;Save in DI
  76.  
  77.         ;Get Source ADDR of Character Bit Map in DS:SI
  78.         ;But first, save colors in lookup table
  79.  
  80.  
  81.         MOV     BX,[BP].GPC_SET_OFS     ;Get OFFSET of Character Set
  82.         MOV     SI,BX                   ;Save in SI for now..
  83.  
  84.         ;Get colors
  85.  
  86.         MOV     AX,[BP].GPC_SET_SEG     ;Segment of Charset
  87.         MOV     ES,AX                   ;Use ES to point to it...
  88.  
  89.         MOV     AL,[BP].GPC_COLORB      ;Get Backgorund color
  90.         MOV     ES:[SI+SCRATCH_OFS],AL  ;Save in Table at Pos (0)
  91.  
  92.         MOV     AL,[BP].GPC_COLORF      ;Forground Color (1)
  93.         MOV     ES:[SI+SCRATCH_OFS+1],AL   ;Save in Table
  94.  
  95.         ;Get addr of character map
  96.  
  97.         MOV     AL,[BP].GPC_CHAR_NUM    ;Get Character #
  98.         AND     AX,007FH                ;Valid #'s are 0..127
  99.         SHL     AX,1                    ;* 2
  100.         SHL     AX,1                    ;* 4
  101.         SHL     AX,1                    ;* 8
  102.  
  103.         MOV     BX,SI                   ;BX = Start of Char Set
  104.         ADD     BX,SCRATCH_OFS          ;BX points to lookup table
  105.  
  106.         ADD     SI,AX                   ;Add Start of Character Set
  107.  
  108.         ;Get segment of character map
  109.  
  110.         MOV     DS,[BP].GPC_SET_SEG     ;Get Segment of Character Set
  111.                                         ;Cant use DS (DGROUP) anymore
  112.  
  113.         MOV     AX,VGA_SEGMENT          ;VGA Graphics Segment
  114.         MOV     ES,AX
  115.         CLD                             ;Forwards....
  116.  
  117.         MOV     CX,8                    ;8 Bytes to Decode
  118.  
  119. DECODE_CHAR_BYTE:
  120.  
  121.         LODSB                           ;Get Byte to decode in DS:SI
  122.         MOV     DL,AL                   ;Save in DL
  123.  
  124.         XOR     DH,DH                   ;Clear DH
  125.         SHL     DX,1                    ;Get Bit #1
  126.         MOV     AL,DH                   ;Put in AL
  127.         XLAT    AL                      ;Translate into DAC value
  128.  
  129.         STOSB                           ;Write to Video Buffer
  130.  
  131.         XOR     DH,DH                   ;Clear DH
  132.         SHL     DX,1                    ;Get Bit #2
  133.         MOV     AL,DH                   ;put in AL
  134.         XLAT    AL                      ;Translate into DAC value
  135.  
  136.         STOSB                           ;Write to Video Buffer
  137.  
  138.         XOR     DH,DH                   ;Clear DH
  139.         SHL     DX,1                    ;Get Bit #3
  140.         MOV     AL,DH                   ;put in AL
  141.         XLAT    AL                      ;Translate into DAC value
  142.  
  143.         STOSB                           ;Write to Video Buffer
  144.  
  145.         XOR     DH,DH                   ;Clear DH
  146.         SHL     DX,1                    ;Get Bit #4
  147.         MOV     AL,DH                   ;put in AL
  148.         XLAT    AL                      ;Translate into DAC value
  149.  
  150.         STOSB                           ;Write to Video Buffer
  151.  
  152.         XOR     DH,DH                   ;Clear DH
  153.         SHL     DX,1                    ;Get Bit #5
  154.         MOV     AL,DH                   ;put in AL
  155.         XLAT    AL                      ;Translate into DAC value
  156.  
  157.         STOSB                           ;Write to Video Buffer
  158.  
  159.         XOR     DH,DH                   ;Clear DH
  160.         SHL     DX,1                    ;Get Bit #6
  161.         MOV     AL,DH                   ;put in AL
  162.         XLAT    AL                      ;Translate into DAC value
  163.  
  164.         STOSB                           ;Write to Video Buffer
  165.  
  166.         XOR     DH,DH                   ;Clear DH
  167.         SHL     DX,1                    ;Get Bit #7
  168.         MOV     AL,DH                   ;put in AL
  169.         XLAT    AL                      ;Translate into DAC value
  170.  
  171.         STOSB                           ;Write to Video Buffer
  172.  
  173.         XOR     DH,DH                   ;Clear DH
  174.         SHL     DX,1                    ;Get Bit #8
  175.         MOV     AL,DH                   ;put in AL
  176.         XLAT    AL                      ;Translate into DAC value
  177.  
  178.         STOSB                           ;Write to Video Buffer
  179.  
  180.         ADD     DI,SCREEN_WIDTH-8       ;Point to Next Line
  181.  
  182.         LOOP    DECODE_CHAR_BYTE        ;Process all Lines
  183.  
  184.         POP     DI
  185.         POP     SI
  186.         POP     DS                      ;Restore Data Segment
  187.         POP     BP                      ;Restore Bp
  188.  
  189.         RET     14                      ;Exit and Clean up Stack
  190.  
  191.  
  192. GPRINTC  ENDP
  193.